Quote
bomz
1 clean the history
2 clean the history of downloads
3 clean cash
4 clean cookies
5 clean saved passwords
6 clean filled forms
you may choose only some of cleaning and do it in one-click
Try with this macro;
Tools -> Privacy -> Clear Data -> Clear Selected
Selected to Clear
P_ClearSelected.kmm
# K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage)
#
# ---------- Privacy Clear Selected options for Privacy menu ----------------------------
#
# Dependencies : $kPrivacy
# Resources : -
# Preferences : p_clearselected.*
# Version : 1.0
# ---------------------------------------------------------------------------------------
#
P_ClearSelected{
macroinfo=_("Clear the selected items");
getpref(BOOL,"p_clearselected.cache")?plugin(privacy,ClearCache):0;
getpref(BOOL,"p_clearselected.cookies")?plugin(privacy,ClearCookies):0;
getpref(BOOL,"p_clearselected.passwords")?plugin(privacy,ClearSignon):0;
getpref(BOOL,"p_clearselected.history")?plugin(privacy,ClearHistory):0;
getpref(BOOL,"p_clearselected.mru")?plugin(privacy,ClearMRU):0;
}
_P_Select_Cache{
menuchecked=getpref(BOOL,"p_clearselected.cache");
togglepref(BOOL,"p_clearselected.cache");
}
_P_Select_Cookies{
menuchecked=getpref(BOOL,"p_clearselected.cookies");
togglepref(BOOL,"p_clearselected.cookies");
}
_P_Select_Passwords{
menuchecked=getpref(BOOL,"p_clearselected.passwords");
togglepref(BOOL,"p_clearselected.passwords");
}
_P_Select_History{
menuchecked=getpref(BOOL,"p_clearselected.history");
togglepref(BOOL,"p_clearselected.history");
}
_P_Select_MRU{
menuchecked=getpref(BOOL,"p_clearselected.mru");
togglepref(BOOL,"p_clearselected.mru");
}
_P_ClearSelected_BuildMenu{
# New menu option in Privacy menu to clear selected:
$kPrivacy?setmenu("&Clear Data",separator,-1):0;
$kPrivacy?setmenu("&Clear Data",macro,_("Clear Selected"),"P_ClearSelected",-1):0;
# New popup menu for Privacy menu to checked:
$kPrivacy?setmenu("&Clear Data",popup,_("Selected to Clear"),-1):0;
$kPrivacy?setmenu("Selected to Clear",macro,"Clear C&ache","_P_Select_Cache",0):0;
$kPrivacy?setmenu("Selected to Clear",macro,"Clear &Cookies","_P_Select_Cookies",1):0;
$kPrivacy?setmenu("Selected to Clear",macro,"Clear Pass&words","_P_Select_Passwords",2):0;
$kPrivacy?setmenu("Selected to Clear",macro,"Clear &History","_P_Select_History",3):0;
$kPrivacy?setmenu("Selected to Clear",macro,"Clear &URL Bar History","_P_Select_MRU",4):0;
}
$OnInit=$OnInit."_P_ClearSelected_BuildMenu;";
$macroModules=$macroModules."P_ClearSelected;";
K-Meleon in Spanish
Edited 1 time(s). Last edit at 07/08/2009 08:34PM by desga2.